# Start by telling Maple that theta is a function of time.
> Theta:=theta(t);
                       Theta := theta(t)
# Then we can enter our Cardioid
> r:=k*(1+cos(Theta));
                   r := k (1 + cos(theta(t)))
# The key thing about our path is that the particle us travelling at
# constant speed so we need to write out the speed.
# The speed depends on dr/dt so let's let Maple evaluate that.
> rdot:=diff(r,t);
                                     / d          \
            rdot := -k sin(theta(t)) |--- theta(t)|
                                     \ dt         /
# Now we can write an equation for the velocity which Maple will assume
# is a constant unless we tell it otherwise.
> eqn1:=v*v=rdot^2+(r*diff(Theta,t))^2;
                                                      2
                  2    2              2 / d          \ 
         eqn1 := v  = k  sin(theta(t))  |--- theta(t)| 
                                        \ dt         / 

                                                    2
               2                    2 / d          \ 
            + k  (1 + cos(theta(t)))  |--- theta(t)| 
                                      \ dt         / 
# Since Maple treats v as a constant we can solve this equation for
# dtheta/dt.
> ans1:=solve(eqn1,diff(Theta,t));
                             (1/2)                           (1/2)  
        (2 - 2 cos(theta(t)))      v    (2 - 2 cos(theta(t)))      v
ans1 := ----------------------------, - ----------------------------
             2 sin(theta(t)) k               2 sin(theta(t)) k      
# Naturally we obtained two solutions, corresponding to going round the
# curve clockwise and anti-clockwise. Let us
# use Maple's selection operator to choose only the first root.
> tdot:=ans1[1];
                                           (1/2)  
                      (2 - 2 cos(theta(t)))      v
              tdot := ----------------------------
                           2 sin(theta(t)) k      
# With that in hand we can go back and pretty up rdot and then plug
# into the acceleration equation to find a.
> rdot:=subs(diff(Theta,t)=tdot,rdot);
                      1                      (1/2)  
            rdot := - - (2 - 2 cos(theta(t)))      v
                      2                             
# To start with we need only the radial component.
> ar:=diff(rdot,t)-r*tdot^2;
                               / d          \
               v sin(theta(t)) |--- theta(t)|
                               \ dt         /
       ar := - ------------------------------
                                       (1/2) 
                2 (2 - 2 cos(theta(t)))      

                                                       2
            (1 + cos(theta(t))) (2 - 2 cos(theta(t))) v 
          - --------------------------------------------
                                          2             
                         4 k sin(theta(t))              
# Woops, there is a dtheta/dt we need to get rid of.
> ar:=subs(diff(Theta,t)=tdot,ar);
            2                                               2
           v     (1 + cos(theta(t))) (2 - 2 cos(theta(t))) v 
   ar := - --- - --------------------------------------------
           4 k                                 2             
                              4 k sin(theta(t))              
# That's dramatic but it is not what we expected. However, we can
# recognise some of the bits of that as double
# angle formula bits so maybe Maple can too.
> ar:=simplify(ar);
                                     2
                                  3 v 
                          ar := - ----
                                  4 k 
# Bingo!
# Now to get the total acceleration we need the angular part as well.
> at:=r*diff(tdot,t)+2*rdot*tdot;
                            /         / d          \       
                            |       v |--- theta(t)|       
                            |         \ dt         /       
at := k (1 + cos(theta(t))) |------------------------------
                            |                       (1/2)  
                            \2 (2 - 2 cos(theta(t)))      k

                          (1/2)                 / d          \\
     (2 - 2 cos(theta(t)))      v cos(theta(t)) |--- theta(t)||
                                                \ dt         /|
   - ---------------------------------------------------------|
                                       2                      |
                        2 sin(theta(t))  k                    /

                            2
     (2 - 2 cos(theta(t))) v 
   - ------------------------
        2 sin(theta(t)) k    
# Again, we need to get rid of the dtheta/dt's.
> at:=subs(diff(Theta,t)=tdot,at);
                            /         2        
                            |        v         
at := k (1 + cos(theta(t))) |------------------
                            |   2              
                            \4 k  sin(theta(t))

                            2              \                          2
     (2 - 2 cos(theta(t))) v  cos(theta(t))|   (2 - 2 cos(theta(t))) v 
   - --------------------------------------| - ------------------------
                             3  2          |      2 sin(theta(t)) k    
              4 sin(theta(t))  k           /                           
# Messy, can a simpler form be found?
> at:=simplify(at);
                                              2
                       3 (cos(theta(t)) - 1) v 
                 at := ------------------------
                          4 sin(theta(t)) k    
# Ready to do magnitude. Let's assume we need a simplify this time!
> asq:=simplify(ar^2+at^2);
                                    4          
                                 9 v           
                asq := ------------------------
                                              2
                       8 (1 + cos(theta(t))) k 
# We recognise that we could bprobably do something with the half-angle
# formula in the denom. Leave it for now.